;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; GNU GENERAL PUBLIC LICENSE ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;; CharityWorld-NL
;; CharityWorld-NL is a model designed to show the emergent effects 
;; of floating-point errors in agent-based models.
;; Copyright (C) 2005 Luis R. Izquierdo
;; 
;; This program is free software; you can redistribute it and/or
;; modify it under the terms of the GNU General Public License
;; as published by the Free Software Foundation; either version 2
;; of the License, or (at your option) any later version.
;; 
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.
;; 
;; You should have received a copy of the GNU General Public License
;; along with this program; if not, write to the Free Software
;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301, USA.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; DECLARATION OF VARIABLES ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; 

globals [ time-step ]

patches-own [ ; patches are the agents. We do not use turtles here
  wealth
  my-neighbors ; these are the 8 neighbours in the Moore neighbourhood of radius 1
]

;;;;;;;;;;;;;;;;;;;;;;;
;;; CORE PROCEDURES ;;;
;;;;;;;;;;;;;;;;;;;;;;;

to setup
  clear-all-plots
  clear-patches  ; we do not clear all to keep the random seed inputted by the user
  output-print "Coin value: " + coin-value
  output-print "Type of agent: " + type-of-agent
  setup-patches
  set time-step 0
  update-graphs 
end

to setup-patches
  ask patches
    [ set wealth coin-value 
      set wealth (wealth + coin-value) ] ; give 2 coins to everyone
  ask patches
    [ set my-neighbors values-from neighbors [self] ] ; convert the agentset primitive "neighbors" into a list
  output-print "Every agent starts with 2 coins"
end

to conduct-lottery
  ; everyone gives two coins to the agent in the centre
  ask patches
    [ give-one-coin-to patch 0 0
      give-one-coin-to patch 0 0 ]
  update-graphs
  output-print "Every agent has given 2 coins to\n\tthe agent in the centre"
end

to go
  let rich-agents patches with [ locally-rich ] ; identify the agents who are locally rich
  ifelse not any? rich-agents 
    [   ; if there's no rich agents, finish the simulation
      output-print "No more locally-rich agents!\nEnd of simulation.\nTime-steps: " + time-step
      stop
    ]
    [   ; if there are, choose one of them at random and tell it to conduct one cycle of redistribution
      ask random-one-of rich-agents [conduct-cycle-of-redistribution] 
      update-graphs
      set time-step (time-step + 1)
    ]
end

to conduct-cycle-of-redistribution 
  ; Give one coin to each of your neighbours in ascending order of wealth as long as:
  ;  1. You are locally rich
  ;  2. Your neighbour isn't
  set my-neighbors shuffle my-neighbors ; make sure there's no bias in ties when we sort the list
  set my-neighbors sort-by [ wealth-of ?1 < wealth-of ?2 ] my-neighbors ; sort the list in ascending order of wealth
  foreach my-neighbors [
    if locally-rich and (not value-from ? [locally-rich]) 
      [ give-one-coin-to ? ]   
  ]
end

to give-one-coin-to [ recipient ]
  set wealth (wealth - coin-value)
  set wealth-of recipient (wealth-of recipient + coin-value)
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; PROCEDURES TO DETERMINE WHETHER AN AGENT IS LOCALLY RICH, AVERAGE, OR POOR ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to-report locally-rich
  ; Four different ways of assessing whether an agent is locally rich or not. 
  ; The four of them are mathematically equivalent in real arithmetic, 
  ; but can give different results in floating-point arithmetic.
  if type-of-agent = "inclusive total" [
    let nbrTotal (sum values-from neighbors [wealth]) + wealth
    ifelse 9 * wealth > nbrTotal 
      [ report true ]
      [ report false ]
  ]  
  if type-of-agent = "inclusive mean" [
    let nbrMean ((sum values-from neighbors [wealth]) + wealth) / 9
    ifelse wealth > nbrMean 
      [ report true ]
      [ report false ]
  ]   
  if type-of-agent = "exclusive total" [
    let nbrTotal (sum values-from neighbors [wealth])
    ifelse 8 * wealth > nbrTotal 
      [ report true ]
      [ report false ]
  ] 
  if type-of-agent = "exclusive mean" [
    let nbrMean (sum values-from neighbors [wealth]) / 8
    ifelse wealth > nbrMean 
      [ report true ]
      [ report false ]
  ]   
end

to-report locally-average
  ; Four different ways of assessing whether an agent is locally average or not. 
  ; The four of them are mathematically equivalent in real arithmetic, 
  ; but can give different results in floating-point arithmetic.
  if type-of-agent = "inclusive total" [
    let nbrTotal (sum values-from neighbors [wealth]) + wealth
    ifelse 9 * wealth = nbrTotal 
      [ report true ]
      [ report false ]
  ]
  if type-of-agent = "inclusive mean" [
    let nbrMean ((sum values-from neighbors [wealth]) + wealth) / 9
    ifelse wealth = nbrMean 
      [ report true ]
      [ report false ]
  ]  
  if type-of-agent = "exclusive total" [
    let nbrTotal (sum values-from neighbors [wealth])
    ifelse 8 * wealth = nbrTotal 
      [ report true ]
      [ report false ]
  ]
  if type-of-agent = "exclusive mean" [
    let nbrMean (sum values-from neighbors [wealth]) / 8
    ifelse wealth = nbrMean 
      [ report true ]
      [ report false ]
  ]  
end

to-report locally-poor
  ; Four different ways of assessing whether an agent is locally poor or not. 
  ; The four of them are mathematically equivalent in real arithmetic, 
  ; but can give different results in floating-point arithmetic.
  if type-of-agent = "inclusive total" [
    let nbrTotal (sum values-from neighbors [wealth]) + wealth
    ifelse 9 * wealth < nbrTotal 
      [ report true ]
      [ report false ]
  ] 
  if type-of-agent = "inclusive mean" [
    let nbrMean ((sum values-from neighbors [wealth]) + wealth) / 9
    ifelse wealth < nbrMean 
      [ report true ]
      [ report false ]
  ] 
  if type-of-agent = "exclusive total" [
    let nbrTotal (sum values-from neighbors [wealth])
    ifelse 8 * wealth < nbrTotal 
      [ report true ]
      [ report false ]
  ]
  if type-of-agent = "exclusive mean" [
    let nbrMean (sum values-from neighbors [wealth]) / 8
    ifelse wealth < nbrMean 
      [ report true ]
      [ report false ]
  ] 
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; GRAPH-RELATED PROCEDURES ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

to update-graphs
  ask patches [ update-colour ]
  set-current-plot-pen "locally-rich" 
    plot count patches with [locally-rich]
  set-current-plot-pen "locally-average" 
    plot count patches with [locally-average]
  set-current-plot-pen "locally-poor" 
    plot count patches with [locally-poor]
end
  
to update-colour 
  if display-mode = "Relative (local) wealth" [
    if locally-rich [ set pcolor green ]
    if locally-average [ set pcolor yellow ]
    if locally-poor [ set pcolor red ]
  ]
  if display-mode = "Absolute wealth" [
    if wealth > 2 * coin-value 
      [ set pcolor (50 + 7 * (((2 * screen-size-x * screen-size-y) - wealth) / (2 * screen-size-x * screen-size-y - 2 * coin-value)) ^ 30) ]
      ; I raise to the power of 30 to make the colour scale finer when the wealth is close to 2 coins
    if wealth < 2 * coin-value [ set pcolor (15 + 5 * wealth / (2 * coin-value)) ]
    ifelse wealth = 2 * coin-value 
      [ set pcolor yellow ]
      ; This final condition, implemented to detect floating-point errors, overrides the previous conditions.
      [ if wealth > 1.5 * coin-value and wealth < 2.5 * coin-value [ set pcolor blue ] ]
  ]
end

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;; RANDOM SEED RELATED PROCEDURES ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; Use a seed created by the new-seed reporter
to use-generated-seed
  output-print "-----NEW RANDOM SEED-----"
  let my-seed new-seed            ; generate a new seed
  output-print "Generated seed: " + my-seed  ; print it out
  random-seed my-seed             ; use the new seed
end

; Use a seed entered by the user
to use-seed-from-user
  output-print "-----NEW RANDOM SEED-----"
  let my-seed read-from-string user-input "Enter a random seed (an integer):"
  output-print "User entered seed: " + my-seed  ; print it out
  random-seed my-seed             ; use the new seed
end

@#$#@#$#@
GRAPHICS-WINDOW
322
11
522
232
7
7
12.7
1
10
1
1
1
0
1
1
1

CC-WINDOW
5
506
709
601
Command Center
0

BUTTON
5
115
68
148
NIL
setup
NIL
1
T
OBSERVER
T
NIL

BUTTON
5
189
68
222
NIL
go
T
1
T
OBSERVER
T
NIL

SLIDER
5
10
177
43
coin-value
coin-value
0
10
1.0
0.1
1
NIL

OUTPUT
6
287
317
492

BUTTON
203
11
317
45
Generate seed
use-generated-seed
NIL
1
T
OBSERVER
T
NIL

BUTTON
203
49
317
82
Input seed
use-seed-from-user
NIL
1
T
OBSERVER
T
NIL

PLOT
322
287
698
492
Number of locally rich, average, and poor agents
Time-step
Count
0.0
10.0
0.0
10.0
true
true
PENS
"locally-rich" 1.0 0 -10899396 true
"locally-average" 1.0 0 -1184463 true
"locally-poor" 1.0 0 -2674135 true

CHOOSER
526
11
698
56
display-mode
display-mode
"Absolute wealth" "Relative (local) wealth"
0

BUTTON
72
189
135
222
step
go
NIL
1
T
OBSERVER
T
NIL

BUTTON
427
235
522
268
update-grid
update-colour
NIL
1
T
PATCH
T
NIL

BUTTON
5
152
110
185
NIL
conduct-lottery
NIL
1
T
OBSERVER
T
NIL

TEXTBOX
528
70
700
205
Absolute wealth legend:\n  Green shades: wealth > 2 coins\n  Yellow:             wealth = 2 coins\n  Red shades:     wealth < 2 coins\n  Blue overrides when: \n           wealth > 1.5 coins   AND\n           wealth < 2.5 coins   AND\n           wealth != 2 coins

TEXTBOX
531
207
680
267
Relative (local) wealth legend:\n  Green:   locally rich \n  Yellow:  locally average\n  Red:      locally poor

BUTTON
6
250
94
283
NIL
clear-output
NIL
1
T
OBSERVER
T
NIL

CHOOSER
5
47
143
92
type-of-agent
type-of-agent
"inclusive total" "inclusive mean" "exclusive total" "exclusive mean"
0

MONITOR
322
235
392
284
NIL
time-step
0
1

TEXTBOX
152
104
316
239
TO RUN THIS MODEL\n1. Choose a coin value.\n2. Select one type of agent.\n3. Use a generated random seed \n    or, alternatively, input one.\n4. Click on setup.\n5. Click on conduct-lottery.\n6. Click on go.

BUTTON
97
250
172
283
NIL
clear-all
NIL
1
T
OBSERVER
T
NIL

@#$#@#$#@
WHAT IS IT?
-----------
CharityWorld-NL is a model designed to show the emergent effects of floating-point errors in agent-based models. This is done by showing how the model behaves dramatically differently using floating-point arithmetic and using real arithmetic.

CharityWorld-NL is a model of wealth redistribution in which a number of spatially embedded agents begin with a highly unequal distribution of wealth. This unequal distribution is then redistributed by the agents using a simple rule determining when and to whom money should be given. 

CharityWorld-NL is an unofficial and reduced version of CharityWorld. CharityWorld-NL should be used for illustration purposes only. You can find the official version of CharityWorld (written in Objective-C) in http://www.macaulay.ac.uk/fearlus/floating-point/charity-world/

HOW IT WORKS
------------
In CharityWorld-NL, the square grid (of default size 15x15) is filled with stationary agents, one per cell. Agents are endowed with an initial wealth of 2 coins.

At the beginning of the simulation agents participate in a lottery for which they have to pay 2 coins as the ticket price. The agent at the centre of the grid happens to be the winner of the lottery so, after the lottery has taken place (i.e. after clicking on "conduct-lottery'), its wealth in coins is equal to the number of agents times 2, while the other agents' wealth is 0.

At any point in time an agent is locally rich (if and only if the agent is richer than its neighbourhood average), locally average (if and only if the agent's wealth is exactly equal to its neighbourhood average), or locally poor (if and only if the agent is poorer than its neighbourhood average). These agents have a strong craving for equality, so if they are locally rich, they are prepared to donate a coin to their neighbours who are not locally rich (an agent's neighbours are the 8 other agents with whom the agent shares an edge or a corner. Topology is toroidal). More specifically, an agent considers its neighbours in ascending order of wealth, and gives one coin to each of them (one neighbour at a time) as long as the donating agent is locally rich and the considered neighbour is not locally rich. This process is called the cycle of redistribution.

Scheduling in the model works as follows: at every time-step a locally rich agent is selected at random and told to perform a cycle of redistribution.

So, to clarify things, the first cycle of redistribution in a simulation run should consist of the lottery winner (who is the only locally rich agent right after the lottery has taken place) giving one coin to each of its neighbours (who are not locally rich). Subsequent cycles of redistribution will also be conducted by the lottery winner until one of its neighbours becomes locally rich and is selected (at random) to perform the cycle of redistribution. At that point, wealth will spread even further, eventually making other neighbouring agents locally rich, and therefore turning them into potential donors. The question is: will wealth be completely redistributed using only this simple local rule?

HOW TO USE IT
-------------
1. Choose a coin value.
This parameter determines the value of the coin used to calculate every agent's wealth.
Please realise that if the model ran without any rounding errors, then the value of the coin would not make any difference whatsoever. Using binary numbers like 0.5, 1.0, 1.5, 2.0, or any other multiple of 0.5, prevents any errors from happening. Thus, the behaviour of the model using any of those numbers is exactly the same (using the same random seed). On the contrary, using numbers like 0.1, 0.2, 0.3, 0.4, 0.6, 0.7, ... causes the appearance of rounding errors and of its undesirable consequences in the emergent properties of the model.

2. Select a type of agent.
Different types of agents use different equations to assess whether they are locally rich, average, or poor. The four equations implemented in CharityWorld-NL are all mathematically equivalent in real arithmetic, but can give different results in floating-point arithmetic.

a) "inclusive total": The two quantities that are compared are the particular agent's wealth multiplied by 9, and the total wealth in the neighbourhood (including the particular agent's wealth). 

b) "inclusive mean": The two quantities that are compared are the particular agent's wealth, and the average wealth in the neighbourhood (including the particular agent's wealth in the calculation of the average). 

c) "exclusive total": The two quantities that are compared are the particular agent's wealth multiplied by 8, and the total wealth in the neighbourhood (excluding the particular agent's wealth). 

d) "exclusive mean": The two quantities that are compared are the particular agent's wealth, and the average wealth in the neighbourhood (excluding the particular agent's wealth in the calculation of the average). 

When using coin values that prevent errors from happening (e.g. integers), the 4 algorithms above give always the same answer. Thus, runs conducted with any of them (using the same random seed) will be exactly the same. On the contrary, when using values that cause floating-point errors to happen (e.g. 0.1, 0.2, 0.3, or 0.4), each implementation gives a different result (if the model is run for long enough). 

3. Use a generated random seed or, alternatively, input one.
To replicate runs, use the same random seed.

4. Click on setup.
At this point every agent will be endowed with 2 coins.

5. Click on conduct-lottery.
Every agent gives the 2 coins to the agent in the centre.

6. Click on go.
A locally rich agent is selected at random and asked to perform the cycle of redistribution.

7. Explore the two display modes.

"Absolute wealth": Each agent is coloured according to the following legend:
a) wealth > 2 * coin-value: green shades. The more wealth, the darker the shade of green.
b) wealth = 2 * coin-value: yellow.
c) wealth < 2 * coin-value: red shades. The less wealth, the darker the shade of red.   
d) Blue overrides when: (wealth > 1.5 * coin-value AND wealth < 2.5 * coin-value AND wealth != 2 * coin-value). Blue will not appear in runs that do not suffer floating-poin errors.

"Relative (local) wealth": Each agent is coloured according to the following legend:
a) locally rich: green
b) locally average: yellow
c) locally poor: red

The button "update-grid" is provided to compare snapshots of the two types of graphs above that refer to the same time-step. When the model is running, the grid is updated every time-step automatically.

THINGS TO NOTICE
----------------
Under real arithmetic, it can be proved that every simulation run should behave in exactly the same way no matter the coin value or the type of agent selected (as long as the same random seed is used). It can also be proved that, under real arithmetic, every simulation run should eventually terminate with all the agents having the initial wealth of 2 coins (wealth is eventually completely redistributed irrespective of the coin value, the type of agent, or the random seed). These results can be checked using coin values that are multiples of 0.5, for which simulations run without errors.

Under floating-point arithmetic, however, the story is very different. There are many parameter values (in fact most of them) for which the coin value makes a difference, the type of agent makes a difference, and wealth is never redistributed. Some coin values that show this type of behaviour are: 0.1, 0.2, 0.3, 0.4, 0.6, 0.7, 0.8, and 0.9.

THINGS TO TRY
-------------
An immediate way of appreciating the impact of floating-point errors in this model is to choose a coin value of 0.4, set the display mode to "Relative (local) wealth", and click on set-up. At this point every agent has a wealth of 0.8, so every agent should be locally average. However, due to floating-point errors, every agent sees itself as locally rich, and therefore it would be willing to perform the cycle of redistribution! This is caused only by floating-point errors.

You can also check that when the value of the coin is a multiple of 0.5 (no floating-point errors occur), simulation runs terminate with all the wealth redistributed, and the behaviour of the model is exactly the same using any type of agent and for any of those coin values (remember to use the same random seed). On the contrary, when using a coin value of 0.4, the behaviour of the model is incorrect (it never terminates), and is dependent on the type of agent selected (but it should not be).

IMPORTANT NOTE
-------------------
It is important to remark that the floating-point problems that this model illustrates are caused strictly by the use of floating point arithmetic, not by the use of Netlogo in particular. FLOATING-POINT PROBLEMS ARE BY NO MEANS SPECIFIC ONLY TO NETLOGO. NetLogo, like most programming environments, operates according to the IEEE 754 standard for floating-point arithmetic. You can expect the exact same behaviour if you implement this model in any other platform that follows the IEEE 754 standard. 

EXTENDING THE MODEL
-------------------
CharityWorld-NL is an unofficial and reduced version of CharityWorld. CharityWorld-NL should only be used for illustration purposes. The official version of CharityWorld, which was created by Gary Polhill and Luis Izquierdo, is more flexible and includes many extensions to this reduced version. You can find the official version of CharityWorld (written in Objective-C) in http://www.macaulay.ac.uk/fearlus/floating-point/charity-world/. 

CharityWorld is written in a manner that follows a fairly standard simple Swarm (http://www.swarm.org ) model implementation, with the exception that all floating point numbers are represented using objects rather than the standard double C data type. These objects all belong to the class DoubleSimple, which contains a double instance variable, and methods to replace the arithmetic operators {+, -, *, /} and the comparison operators. Subclasses of DoubleSimple implement various techniques to deal with floating-point problems (e.g. tolerance windows, offsets, interval arithmetic, strings...), and DoubleSimple features creation methods that cause all new floating point objects to belong to one of these subclasses rather than DoubleSimple itself. The user can therefore specify which subclass of Double-Simple they wish to use throughout a particular simulation, and hence which technique will be used to manage floating point issues.

For a detailed description of CharityWorld, see:
Polhill, J.G., Izquierdo, L.R. and Gotts, N.M. (in press)
What every agent-based modeller should know about floating point arithmetic.
Environmental Modelling and Software.
http://www.sciencedirect.com/science/journal/13648152

RELATED MODELS
--------------
CharityWorld-NL is an unofficial and reduced version of CharityWorld. The official version of CharityWorld, which was created by Gary Polhill and Luis Izquierdo, is more flexible and includes many extensions to this reduced version. You can find the official version of CharityWorld (written in Objective-C) in http://www.macaulay.ac.uk/fearlus/floating-point/charity-world/. 

CREDITS AND REFERENCES
----------------------
CharityWorld-NL has been implemented by Luis Izquierdo. CharityWorld-NL is available online at: http://www.macaulay.ac.uk/fearlus/floating-point/charity-world/

If you are interested in the effects of floating-point errors on agent-based models you might want to read the following papers:

Polhill, J.G., Izquierdo, L.R. and Gotts, N.M. (in press)
What every agent-based modeller should know about floating point arithmetic. 
Environmental Modelling and Software.
http://www.sciencedirect.com/science/journal/13648152

Izquierdo, L.R. and Polhill, J.G. (2005)
Is your model susceptible to floating point errors? - and if so... does it really matter?. 
In Troitzsch K.G. (ed.) Proceedings of the 3rd Annual Conference of the European Social Simulation Association.
Available upon request (l.izquierdo@macaulay.ac.uk).

Polhill, J.G., Izquierdo, L.R. and Gotts, N.M. (2005)
The ghost in the model (and other effects of floating point arithmetic). 
Journal of Artificial Societies and Social Simulation 8(1).
http://jasss.soc.surrey.ac.uk/8/1/5.html 

Polhill, J.G. and Izquierdo, L.R. (2005)
Lessons learned from converting the Artificial Stock Market to interval arithmetic.
Journal of Artificial Societies and Social Simulation 8(2).
http://jasss.soc.surrey.ac.uk/8/2/2.html





@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 3.0
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@